Ticket #28347: my.emacs

;; *********************************************
;; ***** Last change: MLO 2011-01-26 08:57 *****
;; *********************************************
;
; This file binds the following keys :
; ------------------------------------
; C-c f: toggle auto-fill mode
; C-c g: move to line nr. N
; C-c r: redraw display

(set-background-color "#F0FFFF")        ; Azure
(set-foreground-color "#000080")        ; Navy blue
(set-cursor-color "#FF0000")            ; Red
(set-mouse-color "#FF7256")             ; Coral1

;; Useful key bindings
;; ===================

(global-set-key "\C-cf" 'auto-fill-mode)
(global-set-key "\C-cg" 'goto-line)
(global-set-key "\C-cr" 'redraw-display)

;; AUCTeX mode for (La)TeX
;; =======================

(setq load-path (cons "/opt/share/emacs/site-lisp" load-path))
(require 'tex-site)

;; Printer settings
;; ================

(setq ps-lpr-command   "lpr"
      ps-lpr-switches  '("-P" "Stylus-D92")
      lpr-command      "lpr"
      lpr-switches     '("-P" "Stylus-D92")
      ps-paper-type    'a4
      ps-print-color-p t)

;; Mail settings
;; =============

(setq mail-host-address "pd.infn.it"
      message-user-organization "I.N.F.N. Padova - CDF/CMS cluster"
      user-mail-address (concat (user-login-name) "@pd.infn.it")
      mail-default-reply-to user-mail-address
      mail-signature t
      message-signature-file (expand-file-name "~/.signature"))

;; Newsreader settings
;; ===================

(setq gnus-select-method '(nntp "powernews.libero.it")
      gnus-local-domain "pd.infn.it"
      gnus-local-organization "I.N.F.N. Padova - CDF/CMS cluster"
      gnus-signature-file (expand-file-name "~/.signature"))

;; Use 'aspell' as spell checker
;; =============================

(setq-default ispell-program-name "/opt/local/bin/aspell")

; This file binds the following keys :
; ------------------------------------
; C-c b:  move point to bottom-left of window
; C-c c:  insert changestamp
; C-c d:  scroll N lines down
; C-c e:  shortcut for set-language-environment
; C-c n:  kill the current line ('n' for 'nuke')
; C-c k:  kill all from point to signature
; C-c p:  toggle show matching parenthesis
; C-c s:  toggle case-sensitive search
; C-c t:  move point to top-left of the window
; C-c T:  toggle tool-bar on and off
; C-c u:  scroll N lines up
; C-c z:  save the whole buffer in the kill ring
; [home]: move point to beginning of file
; [end]:  move point to end of file
; [f13]:  toggle insert/overwrite mode

;; Cosmetics
;; =========

(unless window-system                        ; When running in an xterm:
  (menu-bar-mode -1)                         ; - disable menu-bar;
  (set-terminal-coding-system 'iso-latin-1)  ; - enable accented characters;
  (setq gnus-visual nil))                    ; - disable gnus font-lock;
 
(column-number-mode 1)                  ; Turn on column number show-up

; (setq frame-title-format "%b")          ; Change title to the name of
;                                         ;   the buffer in current window 
(cond ((fboundp 'global-font-lock-mode) ; Turn on font-lock in all
       (global-font-lock-mode t)        ;   modes that support it 
       (setq font-lock-maximum-decoration t) ; Customize colors
       )
      ((fboundp 'turn-on-font-lock)
       (turn-on-font-lock)
       (setq font-lock-maximum-decoration t)))

; The following instruction is not recognized under Mac OS X

;(set-scroll-bar-mode 'right)           ; Scroll-bar position: on the
(cond ((commandp 'toggle-scroll-bar)    ; right 
       (toggle-scroll-bar 1)))

(setq inhibit-startup-message t)        ; Don't show the startup
                                        ; message 

(setq next-line-add-newlines nil)       ; Don't add newlines when
                                        ; moving the cursor past EOF

(fset 'yes-or-no-p 'y-or-n-p)           ; Take y for yes, n for no

(global-set-key "\C-ce"                 ; Use "C-c e" to toggle the language
  'set-language-environment)            ;   (Latin-1 ->Latin-9 for the Euro)

;; Selects the mouse wheel scroll amount
;; =====================================
 
(setq mouse-wheel-scroll-amount
      (quote (3 ((shift) . 1) ((control) . nil))))

;; Load the "show matching parentheses" package
;; ============================================

(require 'paren)                        ; Load
(global-set-key "\C-cp"                 ; Use "C-c p" to toggle the
  'toggle-highlight-paren-mode)         ;   highlight mode
(show-paren-mode t)                     ; Set highlight mode on by default

;; AUCTeX specific
;; ===============

(setq TeX-parse-self t                       ; Enable parse file on load
      TeX-auto-save nil                      ; Disable parse info saving
      TeX-auto-untabify t                    ; Change tabs to spaces
      font-latex-fontify-sectioning 'color)  ; Title highligh. w/ color

;; Useful key bindings
;; ===================

(global-set-key [home] 'beginning-of-buffer)
(global-set-key [end] 'end-of-buffer)
(global-set-key "\C-cs" 'toggle-case-fold-search)
(global-set-key [f13] 'overwrite-mode)

;; Newsreader settings
;; ===================

(setq gnus-subscribe-hierarchical-interactive t
      gnus-interactive-catchup nil
      gnus-large-newsgroup 300)

(setq gnus-article-display-hook
      '(gnus-article-strip-leading-blank-lines
        gnus-article-remove-trailing-blank-lines
        gnus-article-strip-multiple-blank-lines
        gnus-article-hide-headers))

(setq gnus-visible-headers nil
      gnus-use-cache nil
      gnus-ignored-headers
      "^Path\\|^Message\\|^Return\\|^Refer\\|^NNTP\\|^X\\|^Mime\\|^Content")

(setq gnus-post-method 'current)

(setq gnus-summary-mode-line-format "Gnus: %G [%A] %Z"
      gnus-article-mode-line-format "Gnus: %G - %S%m"
      gnus-treat-display-smileys nil)

;; Sets, for the newsreader, the content of the 'Address', 'Reply-To'
;; and 'signature-file' variables in such a way that the resulting
;; post will point to a fake sender.  For the mail agent, these fields
;; have the correct values.

(setq gnus-posting-styles
      '((".*"
         (signature-file (expand-file-name "~/.signature"))
         (address "loreti@pd.infn.it")
         (Reply-to "loreti@pd.infn.it"))
        ((message-news-p)
         (signature-file (expand-file-name "~/.news-signature"))
         (address "mlo@foobar.it")
         (Reply-to "mlo@foobar.it"))))

;; Use "safari" as WWW browser

(setq browse-url-browser-function 'browse-url-generic
      browse-url-generic-program "safari")

;; kill-to-signature
;; -----------------
;; The following function will kill all the text from the point to the
;; first line that starts with "-- ".  This is useful when replying to
;; a long email, but you don't want the rest of the quoted reply.  The
;; function is globally is bounded to C-c k.

(defun kill-to-signature ()
  "Kill all text from point to the first line that starts with \"-- \".
Usually that's the signature."
  (interactive)
  (delete-region (point)
                 (save-excursion
                   (search-forward-regexp "^-- ")
                   (beginning-of-line)
                   (point)))
  (insert "\n\n\n")
  (previous-line 2))

(global-set-key "\C-ck" 'kill-to-signature)

;; Indentation by blanks only
;; ==========================

(setq-default indent-tabs-mode nil)

;; Enable some disabled commands
;; =============================

(put 'downcase-region 'disabled nil)
(put 'upcase-region   'disabled nil)
(put 'eval-expression 'disabled nil)

;; Turn on auto-fill mode for text-, TeX- and Mail- buffers
;; ========================================================

(add-hook 'text-mode-hook '(lambda ()
  (progn (setq fill-column 70) (turn-on-auto-fill))))

(add-hook 'LaTeX-mode-hook '(lambda ()
  (progn (setq fill-column 60) (turn-on-auto-fill))))

(add-hook 'mail-mode-hook  '(lambda ()
  (progn (setq fill-column 72) (turn-on-auto-fill))))

;; Kill the current line (binded to C-c n)
;; =======================================

; Define a variable which will store the previous column position

(defvar previous-column nil "Save the column position")

; Define the nuke-line function: the current line is killed, the
; newline character is deleted, and the cursor is left on the same
; column on the next line.  Because the kill-line function is used,
; the line can be later restored by using the yank commands.

(defun nuke-line()
  "Kill an entire line, including the trailing newline character"
  (interactive)

  ; Store the current column position, and move the cursor to the end
  ; of the current line.

  (setq previous-column (current-column))
  (end-of-line)

  ; If the length of the line is 0, there is no line.  Only the
  ; newline character is deleted.

  (if (= (current-column) 0)
    (delete-char 1)

    ; This is the 'else' clause.  Remove the line by moving to its
    ; start and then killing, then deleting the newline character, and
    ; finally restoring the column position.

    (progn
      (beginning-of-line)
      (kill-line)
      (delete-char 1)
      (move-to-column previous-column))))

(global-set-key "\C-cn" 'nuke-line)

;; changestamps
;; ============

;; Insert "changestamp" at point (binded to C-c c)
;; -----------------------------------------------

(defvar changestamp-prefix "Last change: MLO " "'changestamp' prefix id")
(defvar changestamp-suffix " *****" "'changestamp' suffix id")

(defun insert-datetime ()
  "Insert YYYY-MM-DD HH:MM at point"
  (insert (format-time-string "%Y-%m-%d %R" (current-time))))

(defun insert-changestamp ()
  "Insert a 'changestamp' at point.
A changestamp begins with 'Last change: MLO ' and whatever follows it,
in a line ended by ' *****'"
  (interactive "*")
  (insert changestamp-prefix)
  (insert-datetime)
  (insert changestamp-suffix))

(global-set-key "\C-cc" 'insert-changestamp)

;; Automatically update the first existing changestamp
;; ---------------------------------------------------

(defun update-changestamp ()
  "Update the first existing 'changestamp'.
A changestamp begins with 'Last change: MLO ' and whatever follows it,
in a line ended by ' *****'"
  (interactive "*")
  (save-excursion
    (save-restriction
      (save-match-data
        (widen)
        (goto-char (point-min))
        (if (search-forward changestamp-prefix nil t)
            (progn (kill-line)
                   (insert-datetime)
                   (insert changestamp-suffix))
          nil)))))

(add-hook 'write-file-hooks 'update-changestamp)

;; Automatically update all existing changestamps
;; ----------------------------------------------

(defun update-all-changestamps ()
  "Update all existing 'changestamps'.
A changestamp begins with 'Last change: MLO ' and whatever follows it,
in a line ended by ' *****'"
  (interactive "*")
  (save-excursion
    (save-restriction
      (save-match-data
        (widen)
        (goto-char (point-min))
        (while (search-forward changestamp-prefix nil t)
          (let ((start (point)))
            (if (re-search-forward
                 (concat (regexp-quote changestamp-suffix) "$")
                 (save-excursion (end-of-line) (point))
                 t)
                (progn (goto-char start)
                       (kill-line)
                       (insert-datetime)
                       (insert changestamp-suffix))))))))
  nil)

;; Cursor and point motion
;; =======================
;; - scroll the window one/N lines at a time up and down
;;   (binded to C-c u and C-c d, or C-u N C-c u/d);
;; - move point to start of top/bottom lines
;;   (binded to C-c t and C-c b)

(defun scroll-n-lines-up (&optional n)
  "Scroll the text up N lines (default: 1)"
  (interactive "P")
  (scroll-up (prefix-numeric-value n)))
(global-set-key "\C-cu" 'scroll-n-lines-up)

(defun scroll-n-lines-down (&optional n)
  "Scroll the text down N lines (default: 1)"
  (interactive "P")
  (scroll-down (prefix-numeric-value n)))
(global-set-key "\C-cd" 'scroll-n-lines-down)

(defun point-to-top ()
  "Move point to top left in this window"
  (interactive)
  (move-to-window-line 0))
(global-set-key "\C-ct" 'point-to-top)

(defun point-to-bottom ()
  "Move point to bottom left in this window"
  (interactive)
  (move-to-window-line -1))
(global-set-key "\C-cb" 'point-to-bottom)

;; Symbolic links
;; ==============

;; Make them read-only
;; -------------------

(defun read-only-if-symlink ()
  "When visiting a symlink, make the buffer read-only"
  (if (file-symlink-p buffer-file-name)
      (progn (setq buffer-read-only t)
             (message "This file is a symlink"))))
(add-hook 'find-file-hooks 'read-only-if-symlink)

;; Define two functions to deal with them
;; --------------------------------------

(defun visit-symlink-target ()
  "Replace this buffer with a buffer visiting the symlink target"
  (interactive)
  (if buffer-file-name
      (let ((target (file-symlink-p buffer-file-name)))
        (if target
            (find-alternate-file target)
          (error "Not visiting a symlink!")))
    (error "Not visiting a file!")))

(defun clobber-symlink ()
  "Replace the symlink with a copy of the target, and make it writable"
  (interactive)
  (if buffer-file-name
      (let ((target (file-symlink-p buffer-file-name)))
        (if target
            (if (yes-or-no-p (format "Replace %s with %s? "
                                    buffer-file-name target))
                (progn (delete-file buffer-file-name)
                       (write-file buffer-file-name)
                       (setq buffer-read-only nil)))
          (error "Not visiting a symlink!")))
    (error "Not visiting a file!")))

;; C-like languages major mode settings
;; ====================================

(defconst my-c-style
  '((c-basic-offset . 2)
    (c-comment-only-line-offset . 0)
    (c-cleanup-list . (brace-else-brace
                       brace-elseif-brace
                       brace-catch-brace
                       empty-defun-braces
                       defun-close-semi
                       list-close-comma
                       scope-operator))
    (c-hanging-braces-alist . ((brace-list-open)
                               (substatement-open after)
                               (block-close . c-snug-do-while)
                               (extern-lang-open after)
                               (class-open after)
                               (defun-open after)))
    (c-offsets-alist . ((statement-block-intro . +)
                        (knr-argdecl-intro . 0)
                        (arglist-intro . +)
                        (substatement-open . +)
                        (label . 0)
                        (statement-cont . +)
                        (case-label . +)
                        (arglist-close . 0))))
  "MLO C programming style")

(defun my-c-mode-common-hook ()
  "Add my personal mode for C programming"
  (c-add-style "MLO" my-c-style t)
; (c-toggle-auto-state 1)
  (c-toggle-hungry-state 1)
; (setq c-echo-syntactic-information-p t)
  (setq indent-tabs-mode nil))

(add-hook 'c-mode-common-hook 'my-c-mode-common-hook)

;; Comment all lines in a region (half-box)
;; ========================================

;; Customisation group, and related variables
;; ------------------------------------------

(defgroup half-box nil
  "Customisation of the 'half-box-comments'."
  :group  'editing
  :prefix "half-box-")
(defcustom half-box-start ",-----"
  "Starting line for 'half-box-comments'."
  :type 'string :group 'half-box)
(defcustom half-box-mid "| "
  "Left border of the 'half-box-comments'."
  :type 'string :group 'half-box)
(defcustom half-box-end "`-----"
  "Ending line for 'half-box-comments'."
  :type 'string :group 'half-box)

;; Create an half-box comment block
;; --------------------------------

(defun half-box-comment (start end)
  "Comment all lines in the region (adding two more lines); 'half-box' style."
  (interactive "*r")
  (save-excursion
    (save-restriction
      (narrow-to-region
       (progn (goto-char start) (beginning-of-line) (point))
       (progn (goto-char end) (end-of-line) (point)))
      (goto-char (point-min))
      (beginning-of-line)
      (insert half-box-start "\n")
      (while (not (eobp))
        (insert half-box-mid)
        (forward-line 1))
      (insert  half-box-end "\n"))))

;; Create an half-box comment block, C/C++ specific
;; ------------------------------------------------

(defun half-cbox-comment (start end)
  "Comment all lines in the region (adding two more lines);
C/C++ program 'half-box' style."
  (interactive "*r")
  (let ((half-box-start "/**") (half-box-mid " | ") (half-box-end "**/"))
    (half-box-comment start end)))

;; Create a full-box comment block, C/C++ specific
;; -----------------------------------------------

(defun full-box-comment (start end)
  "Comment all lines in the region (adding two more lines); 'full-box' style."
  (interactive "*r")
  (save-excursion
    (save-restriction
      (narrow-to-region
       (progn (goto-char start) (beginning-of-line) (point))
       (progn (goto-char end) (end-of-line) (point)))
      (delete-trailing-whitespace)
      (goto-char (point-min))           ; Compute in "maxlen" the length of
      (beginning-of-line)               ; the longest line, plus 1.
      (let ((maxlen 0) (pos (point)) (linelen 0))
        (while (= 0 (forward-line))
          (setq maxlen (max maxlen (- (point) pos))
                pos (point)))           ; End <while loop on lines>
        (goto-char (point-min))         ; Insert upper border
        (beginning-of-line)
        (insert "/*")
        (setq linelen maxlen)
        (while (>= linelen 0) (insert "-") (setq linelen (1- linelen)))
        (insert "*\n")
        (setq linelen 0 pos (1- (point)))
        (while (not (eobp))             ; Insert left and right border
          (insert " | ")                ; for every line
          (end-of-line)
          (setq linelen (- (- (point) pos) 3))
          (while (< linelen maxlen) (insert " ") (setq linelen (1+ linelen)))
          (insert " |")
          (setq pos (point))
          (forward-line 1))             ; End <while loop on lines>
        (insert " *")                   ; Insert lower border
        (while (>= maxlen 0) (insert "-") (setq maxlen (1- maxlen)))
        (insert "*/\n"))))              ; End <save-excursion>
  (forward-line 1))                     ; Restore point

;; Save the whole buffer into the kill ring and the X clipboard:
;; - this function is also binded to 'C-c z';
;; - this function is also binded to the first entry in the
;;   "Edit" menu, that will have title "Store buffer".
;; -------------------------------------------------------------

(defun save-whole-buffer ()
  "Select the whole buffer, and copy the selection to the kill ring"
  (interactive)
  (save-excursion
    (save-restriction
      (widen)
      (clipboard-kill-ring-save (point-min) (point-max))
      (message "The whole buffer has been stored in the kill ring"))))

(global-set-key "\C-cz" 'save-whole-buffer)

;; End of /home/loreti/local_emacs.el
;; ==================================

;; End of .emacs
;; =============